Каталог решений - Вызов «настроенного» отчета «Анализ субконто».

Один из самых любимых отчетов бухгалтера – «Анализ субконто», но пользоваться им довольно муторно. Нужно выбрать субконто для анализа и установить по ним отбор. Зачастую этот отчет используется для анализа взаиморасчетов.

Данное решение позволяет вызвать отчет «Анализ субконто» из списка справочника «Контрагенты» с уже установленными субконто: Контрагенты, Договора контрагентов и Документы расчетов (если взаиморасчеты по договору ведутся по расчетным документам), с установленным отбором по позиционированному в списке Контрагенту и по его Договорам (можно выбрать отдельные договора из предложенного списка).

Аналогично в списке Договоров вызывается «Анализ субконто» по текущему Контрагенту (Владельцу договора), Договору и при необходимости расчетным документам.

РЕАЛИЗАЦИЯ:

1)     1)  В общем модуле вставляется процедура:

Процедура ВызовОтчета_АнализСубконто(Контрагент, Договор=Неопределено) Экспорт

Если НЕ ЗначениеЗаполнено(Контрагент) Тогда
Сообщить(«Нет контрагента для анализа», СтатусСообщения.Информация);
Возврат;
КонецЕсли;

Если ТипЗнч(Контрагент)<>Тип(«СправочникСсылка.Контрагенты») Тогда
Сообщить(«Передана ссылка не на контрагента», СтатусСообщения.Информация);
Возврат;
КонецЕсли;

СписокОтбора=НОВЫЙ СписокЗначений;

СписокДоговоров=НОВЫЙ СписокЗначений;

Если Договор=Неопределено Тогда
//Выберем все договора по контрагенту
выбДоговоров=Справочники.ДоговорыКонтрагентов.Выбрать( , Контрагент);
Инд=0;
Пока выбДоговоров.Следующий() Цикл
СписокОтбора.Вставить(Инд, выбДоговоров.Ссылка, СокрЛП(выбДоговоров)+» («+Формат(выбДоговоров.Дата,»ДФ=d.M.yy»)+»)», Истина);
Инд=Инд+1;
КонецЦикла;

Если СписокОтбора.Количество()=0 Тогда
Сообщить(«У контрагента нет договоров», СтатусСообщения.Информация);
Возврат;
КонецЕсли;

Если СписокОтбора.ОтметитьЭлементы(НСтр(«ru = ‘Отберите нужные договора — ‘; uk = ‘Оберіть потрібні договори — ‘»)+СокрЛП(Контрагент)) Тогда
Для Каждого Элемент ИЗ СписокОтбора Цикл
Если Элемент.Пометка Тогда
СписокДоговоров.Добавить(Элемент.Значение);
КонецЕсли;
КонецЦикла;
Иначе
Сообщить(«Отказ пользователя»,СтатусСообщения.Информация);
Возврат;
КонецЕсли;

Если СписокДоговоров.Количество()=0 Тогда
Сообщить(«Не выбраны договора для анализа»,СтатусСообщения.Информация);
Возврат
КонецЕсли;

КонецЕсли;

ФормаОтчета = Отчеты.АнализСубконтоХозрасчетный.ПолучитьФорму();
ФормаОтчета.Открыть();

ФормаОтчета.ДатаКон=КонецДня(ТекущаяДата());
ФормаОтчета.ДатаНач=Дата(«00010101»);
ФормаОтчета.Организация=глЗначениеПеременной(«ОсновнаяОрганизация»);

ФормаОтчета.ПоВалютам=Истина;
ФормаОтчета.ПоСубсчетам=Истина;

//очистим настройки если есть
Пока ФормаОтчета.Субконто.Количество()>0 Цикл
ФормаОтчета.Субконто.Удалить(0);
КонецЦикла;

НоваяСтрока = ФормаОтчета.Субконто.Добавить();
НоваяСтрока.ВидСубконто = ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Контрагенты;
НоваяСтрока = ФормаОтчета.Субконто.Добавить();
НоваяСтрока.ВидСубконто = ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Договоры;

Если Договор=Неопределено Тогда
Для КАЖДОГО стрДоговоров ИЗ СписокДоговоров Цикл
Если стрДоговоров.Значение.ВедениеВзаиморасчетов=Перечисления.ВедениеВзаиморасчетовПоДоговорам.ПоРасчетнымДокументам Тогда
НоваяСтрока = ФормаОтчета.Субконто.Добавить();
НоваяСтрока.ВидСубконто = ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ДокументыРасчетовСКонтрагентами;
Прервать;
КонецЕсли;
КонецЦикла;
Иначе
Если Договор.ВедениеВзаиморасчетов=Перечисления.ВедениеВзаиморасчетовПоДоговорам.ПоРасчетнымДокументам Тогда
НоваяСтрока = ФормаОтчета.Субконто.Добавить();
НоваяСтрока.ВидСубконто = ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ДокументыРасчетовСКонтрагентами;
КонецЕсли;
КонецЕсли;

Пока ФормаОтчета.ПостроительОтчета.Отбор.Количество()>0 Цикл
//Удалим отборы
ФормаОтчета.ПостроительОтчета.Отбор.Удалить(0);
КонецЦикла;

ФормаОтчета.ПостроительОтчета.ЗаполнитьНастройки();

Отбор=ФормаОтчета.ПостроительОтчета.Отбор;
Имя=ФормаОтчета.ПостроительОтчета.ДоступныеПоля.Субконто1.ПутьКДанным;

Отбор.Добавить(Имя, Имя, СокрЛП(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Контрагенты.Наименование));
Отбор[Имя].Использование=Истина;
Отбор[Имя].ВидСравнения=ВидСравнения.Равно;
Отбор[Имя].Значение=Контрагент;

Имя=ФормаОтчета.ПостроительОтчета.ДоступныеПоля.Субконто2.ПутьКДанным;
Отбор.Добавить(Имя, Имя, СокрЛП(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Договоры.Наименование));
Если Договор=Неопределено Тогда
Если СписокДоговоров.Количество()=0 Тогда
Сообщить(«Нет договоров для анализа», СтатусСообщения.Важное);
Возврат;
ИначеЕсли СписокДоговоров.Количество()=1 Тогда
Отбор[Имя].Использование=Истина;
Отбор[Имя].ВидСравнения=ВидСравнения.Равно;
Отбор[Имя].Значение=СписокДоговоров.Получить(0).Значение;
Иначе
Отбор[Имя].Использование=Истина;
Отбор[Имя].ВидСравнения=ВидСравнения.ВСписке;
Отбор[Имя].Значение=СписокДоговоров;
КонецЕсли;
Иначе
Отбор[Имя].Использование=Истина;
Отбор[Имя].ВидСравнения=ВидСравнения.Равно;
Отбор[Имя].Значение=Договор;
КонецЕсли;

ФормаОтчета.ПерезаполнитьНачальныеНастройки();
Порядок=ФормаОтчета.ПостроительОтчета.Порядок;
Порядок.Добавить(«Субконто2.Дата»,»ДоговорыДата»,СокрЛП(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Договоры.Наименование)+».Дата», НаправлениеСортировки.Возр);

ФормаОтчета.ОбновитьОтчет();

КонецПроцедуры

2)  В форме «ФормаСписка» справочника «Контрагенты» добавляется кнопка в действие которой записывается:

                ТД=ЭлементыФормы.СправочникСписок.ТекущиеДанные;

                .ВызовОтчета_АнализСубконто(ТД.Ссылка,Неопределено);

2)      3) В форме «ФормаСписка» справочника «ДоговорыКонтрагентов» добавляется кнопка в действие которой записывается:

        ТД=ЭлементыФормы.СправочникСписок.ТекущиеДанные;

        .ВызовОтчета_АнализСубконто(ТД.Владелец,ТД.Ссылка);

ВСЁ!  Можно пользоваться.